# Exporting starred articles - iOS

**URL:** <https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461>\
**Category:** App\
**Created:** [October 28, 2026, 4:35am UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461 "2026-10-28T04:35:40Z")\
**Posts on this page:** 5\
**Page:** 1

<div class="post-metadata">

**Author:** ![Dandada](https://discourse.netnewswire.com/letter_avatar_proxy/v4/letter/d/b77776/32.png) [@Dandada](https://discourse.netnewswire.com/u/Dandada)\
**Post date:** [October 28, 2026, 4:35am UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461/1 "2026-10-28T04:35:40Z")

</div>

Is there a way to export a complete database of all stared articles from an iOS local account? Even just a list of URLs from my starred articles?

(Hoping to be able to port a complete history of saved NetNewsWire articles into Obsidian).

---

<div class="post-metadata">

**Author:** ![YT04KA](https://discourse.netnewswire.com/letter_avatar_proxy/v4/letter/y/5f9b8f/32.png) [@YT04KA](https://discourse.netnewswire.com/u/YT04KA)\
**Post date:** [October 28, 2026, 11:44am UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461/2 "2026-10-28T11:44:57Z")

</div>

I had a similar idea of saving articles to Obsidian, but I solved it with the Shortcuts help. A shortcut can be made which would get the article text from safari’s reader view, convert it to markdown and then save vault folder.

I guess this won’t help much if you already have a huge backlog of starred articles but it’s something you can do.

---

<div class="post-metadata">

**Author:** ![Dandada](https://discourse.netnewswire.com/letter_avatar_proxy/v4/letter/d/b77776/32.png) [@Dandada](https://discourse.netnewswire.com/u/Dandada)\
**Post date:** [October 28, 2026, 3:10pm UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461/3 "2026-10-28T15:10:17Z")

</div>

Yeah, relatively easy— although not as convenient as just pressing one button in app— to use share functions with some automation to do that on an individual basis in the future.

I’m specifically looking for some sort of portability solution for existing starred articles though.

---

<div class="post-metadata">

**Author:** ![brent](https://discourse.netnewswire.com/user_avatar/discourse.netnewswire.com/brent/32/7_2.png) [@brent](https://discourse.netnewswire.com/u/brent)\
**Post date:** [October 28, 2026, 4:44pm UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461/4 "2026-10-28T16:44:25Z")

</div>

There’s a ticket on the bug tracker for this. I can see how it would be useful, for sure.

For now, though: If you’re syncing to the Mac, you could run an AppleScript script for this. Here’s a quick one that exports URLs:

```auto
-- This script saves the URL of every article in the Starred smart feed to "Starred URLs.txt" on the desktop, one URL per line.

property outputFileName : "Starred URLs.txt"

-- Gather the URLs, one per line
-- the Starred smart feed includes only active accounts, so inactive accounts are skipped

set outputText to ""
tell application "NetNewsWire"
	repeat with nthAccount in (every account where active is true)
		repeat with nthFeed in (allFeeds of nthAccount)
			repeat with nthArticle in (get every article of nthFeed where starred is true)
				set articleURL to url of nthArticle
				if articleURL is not missing value then
					set outputText to outputText & articleURL & linefeed
				end if
			end repeat
		end repeat
	end repeat
end tell

-- Write the file, replacing any existing contents

set outputPath to (path to desktop folder as text) & outputFileName
set outputFile to open for access file outputPath with write permission
try
	set eof outputFile to 0
	write outputText to outputFile as «class utf8»
	close access outputFile
on error errorMessage
	close access outputFile
	error errorMessage
end try

```

---

<div class="post-metadata">

**Author:** ![Dandada](https://discourse.netnewswire.com/letter_avatar_proxy/v4/letter/d/b77776/32.png) [@Dandada](https://discourse.netnewswire.com/u/Dandada)\
**Post date:** [October 28, 2026, 6:45pm UTC](https://discourse.netnewswire.com/t/exporting-starred-articles-ios/461/5 "2026-10-28T18:45:59Z")

</div>

I am not a mac user at the moment, but if this is the only option I will find one to use, sync it, and give that a go.

Thanks!
